root/misc/pmsetup

Revision 2037 (checked in by miyagawa, 13 years ago)

remove 9*.t

  • Property svn:executable set to *
Line 
1 #!/usr/bin/perl
2 use strict;
3 use warnings;
4 use ExtUtils::MakeMaker qw(prompt);
5 use File::Basename;
6 use File::Path;
7 use File::Spec;
8 use Template;
9 use YAML;
10
11 my $path   = File::Spec->catfile($ENV{HOME}, "/.pmsetuprc");
12 my $config = eval { YAML::LoadFile($path) } || {};
13
14 my $save;
15 while (! $config->{author}) {
16     $config->{author} = prompt("Your name: ", '');
17     $save++;
18 }
19
20 while (! $config->{email}) {
21     $config->{email} = prompt("Your email: ", '');
22     $save++;
23 }
24
25 my $modname = shift @ARGV or die "Usage: $0 module\n";
26    $modname =~ s/-/::/g;
27
28 write_plugin_files($modname, $config);
29
30 END {
31     YAML::DumpFile($path, $config) if $save;
32 }
33
34 sub write_plugin_files {
35     my($module, $config) = @_;
36
37     # $module = "Foo::Bar"
38     # $dist   = "Foo-Bar"
39     # $path   = "Foo/Bar.pm"
40     my @pkg  = split /::/, $module;
41     my $dist = join "-", @pkg;
42     my $path = join("/", @pkg) . ".pm";
43
44     mkdir $dist, 0777;
45     chdir $dist;
46
47     my @template = YAML::Load(join '', <DATA>);
48     my $vars = { module => $module, dist => $dist, path => $path,
49                  config => $config, localtime => scalar localtime };
50
51     for my $tmpl (@template) {
52         my $file = $tmpl->{file};
53            $file =~ s/(\$\w+)/$1/eeg;
54         write_file($file, $tmpl->{template}, $vars);
55     }
56
57     !system "perl Makefile.PL" or die $?;
58     !system 'make test' or die $?;
59     !system 'make manifest' or die $?;
60     !system 'make distclean' or die $?;
61 }
62
63 sub write_file {
64     my($path, $template, $vars) = @_;
65
66     if (-e $path) {
67         my $ans = prompt("$path exists. Override? [yN] ", 'n');
68         return if $ans !~ /[Yy]/;
69     }
70
71     my $dir = File::Basename::dirname($path);
72     unless (-e $dir) {
73         warn "Creating directory $dir\n";
74         File::Path::mkpath($dir, 1, 0777);
75     }
76
77     my $tt = Template->new;
78     $tt->process(\$template, $vars, \my $content);
79
80     warn "Creating $path\n";
81     open my $out, ">", $path or die "$path: $!";
82     print $out $content;
83     close $out;
84 }
85
86 __DATA__
87 ---
88 file: Makefile.PL
89 template: |
90   use inc::Module::Install;
91   name '[% dist %]';
92   all_from 'lib/[% path %]';
93
94   build_requires 'Test::More';
95   use_test_base;
96   auto_include;
97   WriteAll;
98
99 ---
100 file: t/00_compile.t
101 template: |
102   use strict;
103   use Test::More tests => 1;
104
105   BEGIN { use_ok '[% module %]' }
106 ---
107 file: t/97_podspell.t
108 template: |
109   use Test::More;
110   eval q{ use Test::Spelling };
111   plan skip_all => "Test::Spelling is not installed." if $@;
112   add_stopwords(<DATA>);
113   all_pod_files_spelling_ok('lib');
114   __DATA__
115   Tatsuhiko
116   Miyagawa
117 ---
118 file: t/98_perlcritic.t
119 template: |
120   use strict;
121   use Test::More;
122   eval q{ use Test::Perl::Critic };
123   plan skip_all => "Test::Perl::Critic is not installed." if $@;
124   all_critic_ok("lib");
125 ---
126 file: t/99_pod.t
127 template: |
128   use Test::More;
129   eval "use Test::Pod 1.00";
130   plan skip_all => "Test::Pod 1.00 required for testing POD" if $@;
131   all_pod_files_ok();
132 ---
133 file: Changes
134 template: |
135   Revision history for Perl extension [% module %]
136
137     0.01  [% localtime %]
138           - original version
139 ---
140 file: lib/$path
141 template: |
142   package [% module %];
143
144   use strict;
145   our $VERSION = '0.01';
146
147   1;
148   __END__
149
150   =head1 NAME
151
152   [% module %] -
153
154   =head1 SYNOPSIS
155
156     use [% module %];
157
158   =head1 DESCRIPTION
159
160   [% module %] is
161
162   =head1 AUTHOR
163
164   [% config.author %] E<lt>[% config.email %]E<gt>
165
166   =head1 LICENSE
167
168   This library is free software; you can redistribute it and/or modify
169   it under the same terms as Perl itself.
170
171   =head1 SEE ALSO
172
173   =cut
174 ---
175 file: MANIFEST.SKIP
176 template: |
177   \bRCS\b
178   \bCVS\b
179   ^MANIFEST\.
180   ^Makefile$
181   ~$
182   \.old$
183   ^blib/
184   ^pm_to_blib
185   ^MakeMaker-\d
186   \.gz$
187   \.cvsignore
188   9.*\.t
189 ---
190 file: README
191 template: |
192   This is Perl module [% module %].
193
194   INSTALLATION
195
196   [% module %] installation is straightforward. If your CPAN shell is set up,
197   you should just be able to do
198
199       % cpan [% module %]
200
201   Download it, unpack it, then build it as per the usual:
202
203       % perl Makefile.PL
204       % make && make test
205
206   Then install it:
207
208       % make install
209
210   DOCUMENTATION
211
212   [% module %] documentation is available as in POD. So you can do:
213
214       % perldoc [% module %]
215
216   to read the documentation online with your favorite pager.
217
218   [% config.author %]
Note: See TracBrowser for help on using the browser.